* RMatch1945y2001.sps.
* Match teeth filled in March 2000 against teeth treated in year ending March 2001.
* Written by PSKL on 21/11/01 and modified on 14/1/02.
* Further revised on 17/2/03.

* Restrict March 2000 data to fillings, plus additional fees.

get file = 'd:\PSKL\Rteeth194510003to10103.sav'.

select if ( fsched = 10003).

select if ( range( trtcode, 1401,1404,1421,1426,1431,1431)).

sort cases by surname initial sex dobirth quadrant tooth doacc (a) trtcode (d).

* flag cases with additional fee treatments.

compute addtrt1=lag(trtcode,1).
compute addtrt2=lag(trtcode,2).
compute addtrt3=lag(trtcode,3).

* flag multiple treatments and dates on the same tooth.

compute duptooth=0.
compute dupacc=0.
compute duptrt=0.

if (surname=lag(surname)
and initial=(lag(initial))
and sex=lag(sex)
and dobirth=lag(dobirth)
and quadrant=lag(quadrant)
and tooth=lag(tooth)) duptooth=1.
If (duptooth=1 and doacc=lag(doacc)) dupacc=1.
If (duptooth=1 and dupacc=1 and trtcode=lag(trtcode))duptrt=1.

if (dupacc=0) addtrt1=0.
if (dupacc=1 and lag(dupacc)=0) addtrt2=0.
if (dupacc=1 and lag(dupacc,2)=0) addtrt3=0.
if (addtrt1=0) addtrt2=0.
if (addtrt1=0) addtrt3=0.
if (addtrt2=0) addtrt3=0.

recode addtrt1,addtrt2,addtrt3
 (0=sysmis).

string addtrt (a14).
compute addtrt=concat(string( addtrt1,f4),'/',string( addtrt2,f4),'/',string( addtrt3,f4)).
Execute.

* save master file of filled teeth.

select if not(any(trtcode,1422,1423,1424,1425,1431)).
Compute Fillrec=1.

* Flag fillings provided under guarantee.

Compute Fguar=0.
If (guarant='G') Fguar=1.

save outfile='c:\temp1.sav'.

* save look-up table for matching.

Compute Filled=1.

Aggregate outfile=* /presorted
 /break surname initial sex dobirth quadrant tooth
 /filled fguar dofacc=first (filled fguar doacc).

save outfile= 'c:\temp2.sav'
 / keep surname initial sex dobirth quadrant tooth filled fguar dofacc.

* Summarise Population.

Aggregate outfile=*
 /presorted
 /break surname initial sex dobirth quadrant tooth
 /n=n.

CROSSTABS
  /TABLES=tooth  BY quadrant  BY sex
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT .

Aggregate outfile=*
 /presorted
 /break surname initial sex dobirth
 /nteeth=n.

CROSSTABS
  /TABLES=nteeth  BY sex
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT .

* Match against quadrant records for next year, but exclude correction records.

get file = 'd:\PSKL\Rteeth194510003to10103.sav'.

sort cases by surname initial sex dobirth quadrant tooth doacc.

Match files file=*
 /table 'c:\temp2.sav'
 /by surname initial sex dobirth quadrant tooth.

select if (filled=1) and not(dofacc=doacc).

Compute fillrec=0.

* Combine with original filling records.

Add files file= 'C:\temp1.sav'
 /file *
 /by surname initial sex dobirth quadrant tooth fillrec.

* Remove additional fee records.

Execute.

select if not (range(trtcode,1431,1431,1422,1425,1541,1541,
   1732,1739,1811,1816,2746,2746,5825,5825)).

save outfile='c:\temp3.sav'.

get file='c:\temp3.sav'.

* Reduce to file of teeth filled in March 2000 schedule, supplemented by time to failure and
* replacement treatment.

sort cases by surname initial sex dobirth quadrant tooth fillrec doacc trtcode.

* Consolidate correction records.

aggregate outfile=*
 /presorted
 /break surname initial sex dobirth quadrant tooth fillrec doacc trtcode
 / fpcnum persnum partnum suffix postcode docomp exempbox
  addtrt1 addtrt2 addtrt3 addtrt quadcode toothpat exempcod fguar guarant =
 first(fpcnum persnum partnum suffix postcode docomp exempbox
  addtrt1 addtrt2 addtrt3 addtrt quadcode toothpat exempcod fguar guarant ).



* Flag replacement fillings provided under guarantee.

Compute Rguar=0.
If (fillrec=0 and guarant='G') Rguar=1.

aggregate outfile=*
 /presorted
 /break surname initial sex dobirth quadrant tooth fillrec doacc
 / fpcnum persnum partnum suffix postcode docomp exempbox
   trtcode addtrt1 addtrt2 addtrt3 addtrt quadcode toothpat exempcod fguar=
 first(fpcnum persnum partnum suffix postcode docomp exempbox
   trtcode addtrt1 addtrt2 addtrt3 addtrt quadcode toothpat exempcod fguar)
 /suptrt=last(trtcode)
 /sumtrt=sum(trtcode)
 /rguar=max(rguar)
 /treats=n.

sort cases by surname initial sex dobirth quadrant tooth fillrec (a) doacc (d).

Do if (fillrec=1 and lag(fillrec)=0).
compute rguar=lag(rguar).
compute time=ctime.days(lag(doacc)-docomp).
if (missing(docomp)) time=ctime.days(lag(doacc)-doacc).
Compute reptreat=lag(trtcode).
* classify as multitreatment when more than one replacement treatment record.
* note that this includes some cases where two replacements of same code.
If (lag(treats)>1) reptreat=9999.
compute reptrt1=lag(trtcode).
if (lag(treats)=2) reptrt2=lag(suptrt).
if (lag(treats)=3) reptrt3=lag(suptrt).
if (lag(treats)=3) reptrt2=lag(sumtrt)-reptrt1-reptrt3.
compute nfpcnum=lag(fpcnum).
compute npersnum=lag(persnum).
compute npartnum=lag(partnum).
compute nsuffix=lag(suffix).
End if.

formats trtcode addtrt1 addtrt2 addtrt3 reptreat reptrt1 reptrt2 reptrt3 (f4.0) tooth (f1.0)
            nfpcnum npartnum (f3.0) npersnum (f6.0) nsuffix(f2.0).

EXECUTE.

* Tidy up the remaining anomalies.
* Assume negative time cases reflect claims out of sequence.
* Censor all cases at 365 days.
Compute failed=0.
Do if (range(time,1,365)).
compute failed=1.
else.
compute time=365.
end if.
If (missing(time))time=365.

EXECUTE.

Select if ( fillrec=1).

EXECUTE.

save outfile='d:\pskl\RMatch1945y2001.sav'.

Get file='d:\pskl\RMatch1945y2001.sav'.


* Produce some tables.

* a) Proportion of early failures, by tooth position, quadrant, type of filling, and patient sex.

Compute failedPC=100*failed.

autorecode VARIABLES= quadrant sex
 /INTO quadn sexn.

Value Labels
 Tooth TRTCODE
1 '1'
2 '2'
3 '3'
4 '4'
5 '5'
6 '6'
7 '7'
8 '8'
1401 '1401'
1402 '1402'
1403 '1403'
1404 '1404'
1421 '1421'
1426 '1426'.

Variable Labels Tooth 'Tooth Position'
 /quadrant quadn 'Quadrant'
 /trtcode 'Treatment Code'.

* Basic Tables.
TABLES
  /FORMAT BLANK MISSING('.')
  /OBSERVATION failedpc
  /FTOTAL $t 'Tooth Summary'
  /TABLES (quadn > failedpc +  $t )
  BY (trtcode +  $t )
  BY (tooth > ((sexn > (STATISTICS) +  $t )))
  /STATISTICS
  mean( (PCT7.1 ))
  count( ( COMMA7.0 )) /TITLE  'Retreatment rates by treatment type, tooth'+
 ' position, quadrant and patient sex'.

* b) Replacement treatment , by type of initial filling.

string retcomb (a14).
compute retcomb=concat(string( reptrt1,f4),'/',string( reptrt2,f4),'/',string( reptrt3,f4)).

Variable Labels retcomb 'Retreatment combination'.

temporary.
select if ( failed=1).

CROSSTABS
  /TABLES=retcomb  BY trtcode  BY tooth
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT COLUMN .